CAPTUR ;NOTE: This is the final version of capture as of
 ;June 9th, 1980   10:18 AM.  This is version 3.5
 ;written in machine language by D.A.G.!
 ;DO NOT COPY!! DO NOT COPY!! DO NOT COPY!! DO NOT COPY!!
 ;
 ;This program will run under any Level II TRS-80.
 ;
 	ORG	0
 	DEFM	'HA HA LMOFFSET !!!'
 	ORG	3C3EH
 	DEFB	138
 	DEFB	138
 	ORG	3C00H
 	DEFM	'LOADING.                                                     '
 	ORG	3C40H
 	DEFM	'                                                                '
 	ORG	3C80H
 	DEFM	'WELCOME TO "CAPTURE" BY DAG !                                   '
 	ORG	3CC0H
 	DEFM	'DISTRIBUTED BY:  ADVENTURE INTERNATIONAL                        '
 	ORG	3C00H+8
 	DEFB	'.'
 	ORG	3D00H
 	DEFM	'BOX 3435 - LONGWOOD, FLORIDA  32750                             '
 	ORG	3D40H
 	DEFM	'                                                                '
 	ORG	4500H
 CURSOR	DEFW	3C00H
 DELAY	DEC	BC
 	LD	A,B
 	OR	C
 	JR	NZ,DELAY
 	RET
 JUMPER	DEFL	$
 	ORG	3C00H+9
 	DEFB	'.'
 	ORG	JUMPER
 	DEFB	2CH
 MYNAME	DI
 	LD	SP,4400H
 OKGO	CALL	ERASE
 	LD	HL,DOUBLE
 	CALL	PRINTM
 	LD	A,44H
 	CALL	AUTHOR
 	LD	A,41H
 	CALL	AUTHOR
 	LD	A,47H
 	CALL	AUTHOR
 	CALL	CLS
 	LD	DE,470
 	CALL	SETCUR
 JUMPER	DEFL	$
 	ORG	3C00H+10
 	DEFB	'.'
 	ORG	JUMPER
 	LD	HL,INTRO
 	CALL	PRINTM
 	LD	BC,5000H
 	CALL	PLAYN
 	LD	BC,6000H
 	CALL	PLAYN
 	LD	DE,470
 	CALL	SETCUR
 	LD	HL,INTRO2
 	CALL	PRINTM
 	LD	BC,5800H
 	CALL	PLAYN
 	LD	BC,6800H
 JUMPER	DEFL	$
 	ORG	3C00H+11
 	DEFB	'.'
 	ORG	JUMPER
 	CALL	PLAYN
 	LD	A,1
 	LD	(NOTE01),A
 START	CALL	CLS
 	LD	HL,INSTR
 	CALL	PRINTM
 GET1	LD	A,(3810H)
 	OR	A
 	JR	Z,GET11
 	LD	C,30H
 GETLP	SRA	A
 	JR	C,FOUND
 JUMPER	DEFL	$
 	ORG	3C00H+12
 	DEFB	'.'
 	ORG	JUMPER
 	INC	C
 	JR	GETLP
 GET11	LD	A,(3820H)
 	AND	3
 	JR	Z,GET1
 	LD	C,38H
 GETLP2	SRA	A
 	JR	C,FOUND
 	INC	C
 	JR	GETLP
 FOUND	LD	A,C
 	PUSH	AF
 JUMPER	DEFL	$
 	ORG	3C00H+13
 	DEFB	'.'
 	ORG	JUMPER
 	CALL	CLS
 	POP	AF
 GET111	AND	0FH
 	LD	(SPEED),A
 BEGIN	JP	REINIT
 JUNK	DEFB	95
 AUTHOR	LD	HL,3C00H
 	LD	DE,3C01H
 	LD	BC,3FFH
 	LD	(HL),A
 	LDIR
 	SLA	A
 JUMPER	DEFL	$
 	ORG	3C00H+14
 	DEFB	'.'
 	ORG	JUMPER
 	LD	B,A
 	LD	C,0
 	PUSH	BC
 	CALL	PLAYN
 	POP	BC
 	CALL	PLAYN
 	RET
 	DEFB	3FH
 CONT	LD	HL,0
 	LD	DE,(X1)
 	LD	IX,X1
 	CALL	GRAFIT
 JUMPER	DEFL	$
 	ORG	3C00H+15
 	DEFB	'.'
 	ORG	JUMPER
 	LD	HL,0
 	LD	DE,(X2)
 	LD	IX,X2
 	CALL	GRAFIT
 	LD	BC,(SPEED)
 	INC	BC
 	LD	B,C
 LOOK10	LD	A,(3802H)
 	OR	A
 	JR	Z,LOOK20
 	BIT	1,A
 	JR	Z,LOOK11
 JUMPER	DEFL	$
 	ORG	3C00H+16
 	DEFB	'.'
 	ORG	JUMPER
 P1UP	LD	HL,0FF00H
 	LD	(DISPX1),HL
 	JR	LOOK20
 LOOK11	BIT	2,A
 	JR	Z,LOOK12
 P1LEFT	LD	HL,00FEH
 	LD	(DISPX1),HL
 	JR	LOOK20
 LOOK12	BIT	3,A
 	JR	Z,LOOK13
 P1RGHT	LD	HL,0002H
 	LD	(DISPX1),HL
 JUMPER	DEFL	$
 	ORG	3C00H+17
 	DEFB	'.'
 	ORG	JUMPER
 	JR	LOOK20
 INTRO	DEFB	23
 	DEFM	'P R E S E N T S'
 	DEFB	0
 LOOK13	BIT	5,A
 	JR	Z,LOOK20
 P1DOWN	LD	HL,0100H
 	LD	(DISPX1),HL
 LOOK20	LD	A,(3804H)
 	BIT	7,A
 	JR	Z,LOOK21
 P2UP	LD	HL,0FF00H
 JUMPER	DEFL	$
 	ORG	3C00H+18
 	DEFB	'.'
 	ORG	JUMPER
 	LD	(DISPX2),HL
 	JR	CONT50
 INTRO2	DEFB	23
 	DEFM	'C A P T U R E !'
 	DEFB	0
 LOOK21	BIT	3,A
 	JR	Z,LOOK22
 P2RGHT	LD	HL,0002H
 	LD	(DISPX2),HL
 	JR	CONT50
 LOOK22	LD	A,(3801H)
 	BIT	1,A
 JUMPER	DEFL	$
 	ORG	3C00H+19
 	DEFB	'.'
 	ORG	JUMPER
 	JR	Z,LOOK23
 P2LEFT	LD	HL,00FEH
 	LD	(DISPX2),HL
 	JR	CONT50
 ERASE	LD	HL,TERMIN
 ERALP	LD	A,0FFH
 	LD	(HL),A
 	CP	(HL)
 	RET	NZ
 	INC	HL
 	LD	A,H
 	OR	A
 	RET	Z
 	JR	ERALP
 LOOK23	LD	A,(3808H)
 	BIT	2,A
 	JR	Z,CONT50
 P2DOWN	LD	HL,0100H
 	LD	(DISPX2),HL
 CONT50	DEC	BC
 	LD	A,B
 	OR	C
 JUMPER	DEFL	$
 	ORG	3C00H+20
 	DEFB	'.'
 	ORG	JUMPER
 	JP	NZ,LOOK10
 TIC	LD	C,10H
 	LD	A,(SOUND)
 	ADD	A,85
 	LD	(SOUND),A
 	LD	B,A
 	CALL	PLAYN
 	LD	HL,(DISPX1)
 	LD	DE,(X1)
 	LD	IX,X1
 	CALL	GRAFIT
 	JP	NZ,LOSER1
 JUMPER	DEFL	$
 	ORG	3C00H+21
 	DEFB	'.'
 	ORG	JUMPER
 	LD	HL,(DISPX2)
 	LD	DE,(X2)
 	LD	IX,X2
 	CALL	GRAFIT
 	JP	NZ,LOSER2
 	JP	CONT
 GRAFIT	LD	A,H
 	ADD	A,D
 	LD	H,A
 	LD	A,L
 	ADD	A,E
 	LD	L,A
 JUMPER	DEFL	$
 	ORG	3C00H+22
 	DEFB	'.'
 	ORG	JUMPER
 	LD	(TEMP),HL
 	LD	A,(3840H)
 	CP	70
 	JP	Z,0
 	LD	DE,(TEMP)
 	CALL	TEST
 	RET	NZ
 	LD	HL,(TEMP)
 	LD	(IX),L
 	INC	IX
 	LD	(IX),H
 	PUSH	HL
 JUMPER	DEFL	$
 	ORG	3C00H+23
 	DEFB	'.'
 	ORG	JUMPER
 	PUSH	HL
 	POP	DE
 	CALL	SET
 	POP	DE
 	LD	A,E
 	INC	A
 	LD	E,A
 	CALL	SET
 	XOR	A
 	RET
 JUMPER	DEFL	$
 	ORG	3C00H+24
 	DEFB	'.'
 	ORG	3C00H+384
 	DEFM	'                                                                '
 	ORG	3C00H+448
 	DEFM	'THIS GAME HAS SOUND!  CONNECT SPEAKER TO TAPE PLAYER WHEN LOADED'
 	ORG	3C00H+512
 	DEFM	'                                                                '
 	ORG	JUMPER
 TEMP	DEFW	0
 SPEED	DEFB	0
 SOUND	DEFB	0
 SCORE1	DEFW	0
 SCORE2	DEFW	0
 X1	DEFB	84
 Y1	DEFB	1AH
 X2	DEFB	42
 Y2	DEFB	1AH
 DISPX1	DEFB	0FEH
 DISPY1	DEFB	0
 DISPX2	DEFB	2
 DISPY2	DEFB	0
 FREQ	DEFB	0
 JUMPER	DEFL	$
 	ORG	3C00H+25
 	DEFB	'.'
 	ORG	JUMPER
 PLAYN	LD	A,B
 	LD	(FREQ),A
 CONT77	LD	A,(FREQ)
 	LD	B,A
 	LD	A,9
 NOTE01	EQU	$-1
 	OUT	(255),A
 LOOP71	DJNZ	$
 	PUSH	AF
 	LD	A,(FREQ)
 	LD	B,A
 	POP	AF
 JUMPER	DEFL	$
 	ORG	3C00H+26
 	DEFB	'.'
 	ORG	JUMPER
 	INC	A
 	OUT	(255),A
 LOOP72	DJNZ	$
 	DEC	C
 	JR	NZ,CONT77
 	RET
 LOSER1	LD	HL,(X2)
 	LD	DE,(TEMP)
 	LD	A,H
 	CP	D
 	JR	NZ,REALL1
 	LD	A,L
 JUMPER	DEFL	$
 	ORG	3C00H+27
 	DEFB	'.'
 	ORG	JUMPER
 	CP	E
 	JR	NZ,REALL1
 TIE	LD	A,R
 	AND	08
 	JR	Z,LOSER2
 REALL1	LD	HL,(SCORE2)
 	INC	HL
 	LD	(SCORE2),HL
 	LD	A,31H
 	LD	(PNUM),A
 	JR	LOSER3
 LOSER2	LD	HL,(SCORE1)
 JUMPER	DEFL	$
 	ORG	3C00H+28
 	DEFB	'.'
 	ORG	JUMPER
 	INC	HL
 	LD	(SCORE1),HL
 	LD	A,32H
 	LD	(PNUM),A
 LOSER3	LD	BC,10
 	LD	DE,902H
 BUZZ	PUSH	BC
 	CALL	PLAYN
 	POP	BC
 	LD	A,B
 	ADD	A,2
 	LD	B,A
 JUMPER	DEFL	$
 	ORG	3C00H+29
 	DEFB	'.'
 	ORG	JUMPER
 	LD	A,B
 	CP	0
 	JR	NZ,BUZZ
 SHAKE	LD	BC,15FFH
 SHAKE2	OUT	(C),D
 	PUSH	BC
 	LD	BC,0B00H
 	CALL	DELAY
 	POP	BC
 	PUSH	BC
 	OUT	(C),E
 	LD	BC,0B00H
 JUMPER	DEFL	$
 	ORG	3C00H+30
 	DEFB	'.'
 	ORG	JUMPER
 	CALL	DELAY
 	POP	BC
 	DJNZ	SHAKE2
 	CALL	BORDER
 TRYAGN	LD	DE,465
 	CALL	SETCUR
 	LD	HL,WINNER
 	CALL	PRINTM
 	LD	DE,530
 	CALL	SETCUR
 	LD	HL,QAGAIN
 	CALL	PRINTM
 JUMPER	DEFL	$
 	ORG	3C00H+31
 	DEFB	'.'
 	ORG	JUMPER
 	LD	DE,658
 	CALL	SETCUR
 	LD	HL,QA2
 	CALL	PRINTM
 	LD	DE,731
 	CALL	SETCUR
 	LD	HL,QA3
 	CALL	PRINTM
 	LD	DE,795
 	CALL	SETCUR
 	LD	HL,QA4
 	CALL	PRINTM
 JUMPER	DEFL	$
 	ORG	3C00H+32
 	DEFB	'.'
 	ORG	JUMPER
 	LD	DE,859
 	CALL	SETCUR
 	LD	HL,QA5
 	CALL	PRINTM
 GET2	LD	A,(3808H)
 	CP	2
 	JR	Z,REINIT
 	LD	A,(3802H)
 	CP	64
 	JR	Z,NOMORE
 	LD	A,(3804H)
 	CP	4
 JUMPER	DEFL	$
 	ORG	3C00H+33
 	DEFB	'.'
 	ORG	JUMPER
 	JR	Z,RESCOR
 	LD	A,(3810H)
 	OR	A
 	JR	Z,GET22A
 	LD	C,30H
 GET22B	SRA	A
 	JR	C,FOUNDA
 	INC	C
 	JR	GET22B
 GET22A	LD	A,(3820H)
 	AND	3
 	JR	Z,GET2
 JUMPER	DEFL	$
 	ORG	3C00H+34
 	DEFB	'.'
 	ORG	JUMPER
 	LD	C,38H
 GET22C	SRA	A
 	JR	C,FOUNDA
 	INC	C
 	JR	GET22C
 FOUNDA	LD	A,C
 	JP	GET111
 RESCOR	LD	HL,0
 	LD	(SCORE1),HL
 	LD	(SCORE2),HL
 	CALL	BRDR1
 	JP	TRYAGN
 JUMPER	DEFL	$
 	ORG	3C00H+35
 	DEFB	'.'
 	ORG	JUMPER
 NOMORE	LD	HL,3000H
 	LD	DE,3001H
 	LD	BC,0
 	LD	(HL),0
 	LDIR
 NOMOR	JR	NOMOR
 REINIT	LD	HL,1A54H
 	LD	(X1),HL
 	LD	L,2AH
 	LD	(X2),HL
 	LD	HL,0FEH
 	LD	(DISPX1),HL
 JUMPER	DEFL	$
 	ORG	3C00H+36
 	DEFB	'.'
 	ORG	JUMPER
 	LD	HL,02
 	LD	(DISPX2),HL
 	CALL	BORDER
 	LD	DE,475
 	CALL	SETCUR
 	LD	HL,GETRDY
 	CALL	PRINTM
 	LD	BC,0
 	CALL	DELAY
 	LD	DE,475
 	CALL	SETCUR
 	LD	HL,GETSET
 JUMPER	DEFL	$
 	ORG	3C00H+37
 	DEFB	'.'
 	ORG	JUMPER
 	CALL	PRINTM
 	LD	BC,0
 	CALL	DELAY
 	LD	DE,475
 	CALL	SETCUR
 	LD	HL,GO
 	CALL	PRINTM
 	LD	BC,8000H
 	CALL	DELAY
 	LD	DE,475
 	CALL	SETCUR
 	LD	HL,CLEAR
 JUMPER	DEFL	$
 	ORG	3C00H+38
 	DEFB	'.'
 	ORG	JUMPER
 	CALL	PRINTM
 	JP	CONT
 WINNER	DEFM	'Player number '
 PNUM	DEFM	'0 has just won!!'
 	DEFB	0
 QAGAIN	DEFM	'Would you like to try again?'
 	DEFB	0
 QA2	DEFM	'Options: "Y" to play again.'
 	DEFB	0
 QA3	DEFM	'"N" to quit.'
 	DEFB	0
 QA4	DEFM	'"R" to reset scores to 0'
 	DEFB	0
 JUMPER	DEFL	$
 	ORG	3C00H+39
 	DEFB	'.'
 	ORG	JUMPER
 QA5	DEFM	'0-9 to choose a new speed'
 	DEFB	0
 CLS	LD	HL,3C00H
 	LD	DE,3C01H
 	LD	BC,1023
 	LD	(HL),20H
 	LDIR
 	XOR	A
 	OUT	(0FFH),A
 	LD	HL,3C00H
 	LD	(CURSOR),HL
 	RET
 SETCUR	LD	HL,3C00H
 	ADD	HL,DE
 JUMPER	DEFL	$
 	ORG	3C00H+40
 	DEFB	'.'
 	ORG	JUMPER
 	LD	(CURSOR),HL
 	RET
 GETRDY	DEFM	'GET READY!!'
 	DEFB	0
 GETSET	DEFM	'GET SET!!!!'
 	DEFB	0
 GO	DEFM	'GO! GO! GO!'
 	DEFB	0
 CLEAR	DEFM	'           '
 	DEFB	0
 PRINTM	LD	A,(HL)
 	OR	A
 JUMPER	DEFL	$
 	ORG	3C00H+41
 	DEFB	'.'
 	ORG	JUMPER
 	RET	Z
 	INC	HL
 	LD	IY,(CURSOR)
 	CP	04
 	JR	Z,SMALL
 	CP	0AH
 	JR	Z,CARRET
 	CP	0DH
 	RET	Z
 	CP	17H
 	JR	Z,BIGGER
 	LD	(IY),A
 JUMPER	DEFL	$
 	ORG	3C00H+42
 	DEFB	'.'
 	ORG	JUMPER
 	CP	(IY)
 	JR	Z,PM3
 	SUB	20H
 	LD	(IY),A
 PM3	INC	IY
 	LD	(CURSOR),IY
 	JR	PRINTM
 CARRET	PUSH	HL
 	PUSH	DE
 	LD	HL,(CURSOR)
 	LD	A,L
 	AND	0C0H
 JUMPER	DEFL	$
 	ORG	3C00H+43
 	DEFB	'.'
 	ORG	JUMPER
 	LD	L,A
 	LD	DE,40H
 	ADD	HL,DE
 	LD	A,H
 	CP	40H
 	LD	(CURSOR),HL
 	CALL	Z,SCROLL
 	POP	DE
 	POP	HL
 	JP	PRINTM
 BIGGER	LD	A,8
 	OUT	(0FFH),A
 	JR	PRINTM
 SMALL	XOR	A
 	OUT	(0FFH),A
 	JR	PRINTM
 SCROLL	LD	DE,3C00H
 	LD	HL,3C40H
 JUMPER	DEFL	$
 	ORG	3C00H+44
 	DEFB	'.'
 	ORG	JUMPER
 	PUSH	BC
 	LD	BC,03C0H
 	LDIR
 	LD	B,40H
 	LD	HL,3FC0H
 SCRLP	LD	(HL),20H
 	INC	HL
 	DJNZ	SCRLP
 	POP	BC
 	LD	HL,3FC0H
 	LD	(CURSOR),HL
 	RET
 	CALL	CLS
 JUMPER	DEFL	$
 	ORG	3C00H+45
 	DEFB	'.'
 	ORG	JUMPER
 BORDER	CALL	BRDR1
 	JR	BRDR2
 BRDR1	LD	DE,0
 	CALL	SETCUR
 	LD	HL,MTITLE
 	CALL	PRINTM
 	LD	HL,(SCORE2)
 	LD	IX,3C16H
 	CALL	CONVRT
 	LD	HL,(SCORE1)
 	LD	IX,3C30H
 	CALL	CONVRT
 JUMPER	DEFL	$
 	ORG	3C00H+46
 	DEFB	'.'
 	ORG	JUMPER
 	RET
 BRDR2	LD	B,0DH
 	LD	DE,128
 	CALL	SETCUR
 LOOP99	LD	HL,SBORDR
 	CALL	PRINTM
 	DJNZ	LOOP99
 	LD	HL,3C42H
 	LD	DE,3C43H
 	LD	BC,3DH
 	LD	(HL),8FH
 	LDIR
 JUMPER	DEFL	$
 	ORG	3C00H+47
 	DEFB	'.'
 	ORG	JUMPER
 	LD	HL,3FC1H
 	LD	DE,3FC2H
 	LD	BC,3EH
 	LD	(HL),0FCH
 	LDIR
 	LD	A,0FFH
 	LD	(3C40H),A
 	LD	(3C7FH),A
 	LD	(3FC0H),A
 	LD	(3FFFH),A
 	LD	(3C7EH),A
 	LD	(3FBFH),A
 JUMPER	DEFL	$
 	ORG	3C00H+48
 	DEFB	'.'
 	ORG	JUMPER
 	LD	(3FFEH),A
 	LD	(3C41H),A
 	LD	(3FC1H),A
 	RET
 CONVRT	LD	IY,P10TAB
 LOOP30	XOR	A
 	LD	E,(IY)
 	LD	D,(IY+1)
 LOOP31	OR	A
 	SBC	HL,DE
 	JP	M,JUMP31
 	INC	A
 JUMPER	DEFL	$
 	ORG	3C00H+49
 	DEFB	'.'
 	ORG	JUMPER
 	JR	LOOP31
 JUMP31	ADD	HL,DE
 	ADD	A,30H
 	LD	(IX),A
 	INC	IX
 	INC	IY
 	INC	IY
 	LD	A,1
 	CP	E
 	JR	NZ,LOOP30
 	RET
 JUMPER	DEFL	$
 	ORG	3C00H+50
 	DEFB	'.'
 	ORG	JUMPER
 P10TAB	DEFW	10000
 	DEFW	1000
 	DEFW	100
 	DEFW	10
 	DEFW	1
 SET	LD	A,0C6H
 	JR	TEST10
 RESET	LD	A,86H
 	JR	TEST10
 TEST	LD	A,46H
 TEST10	LD	(INST+1),A
 JUMPER	DEFL	$
 	ORG	3C00H+51
 	DEFB	'.'
 	ORG	JUMPER
 ADDRES	LD	A,D
 	LD	B,0FFH
 LOOP	INC	B
 	SUB	3
 	JP	P,LOOP
 	ADD	A,3
 	SLA	A
 	LD	C,A
 	LD	L,B
 	LD	H,0
 	LD	B,6
 LOOP1	ADD	HL,HL
 JUMPER	DEFL	$
 	ORG	3C00H+52
 	DEFB	'.'
 	ORG	JUMPER
 	DJNZ	LOOP1
 	LD	D,0
 	SRL	E
 	JR	NC,CONTIN
 	INC	C
 CONTIN	ADD	HL,DE
 	LD	DE,3C00H
 	ADD	HL,DE
 	LD	A,(HL)
 	CP	80H
 	JP	P,SET2
 	LD	(HL),80H
 JUMPER	DEFL	$
 	ORG	3C00H+53
 	DEFB	'.'
 	ORG	JUMPER
 SET2	SLA	C
 	SLA	C
 	SLA	C
 	LD	A,(INST+1)
 	ADD	A,C
 	LD	(INST+1),A
 INST	DEFB	0CBH
 	DEFB	0
 	RET
 JUMPER	DEFL	$
 	ORG	3C00H+54
 	DEFB	'.'
 	ORG	JUMPER
 SBORDR	DEFW	0BFBFH
 	DEFM	'                                                            '
 	DEFW	0BFBFH
 	DEFB	00
 JUMPER	DEFL	$
 	ORG	3C00H+55
 	DEFB	'.'
 	ORG	JUMPER
 MTITLE	DEFM	'SCORE #=#= >>>  LEFT:         CAPTURE    RIGHT:         <<< =#=#'
 	DEFB	0
 INSTR	DEFM	'This is the game of capture.  Each '
 	DEFM	'player will steer his/her ownline '
 JUMPER	DEFL	$
 	ORG	3C00H+56
 	DEFB	'.'
 	ORG	JUMPER
 	DEFM	'around the screen.  A player loses '
 	DEFM	'when his line hits some-thing white '
 	DEFM	'(including the walls, the other player'
 JUMPER	DEFL	$
 	ORG	3C00H+57
 	DEFB	'.'
 	ORG	JUMPER
 	DEFM	' or himself!!)There will be '
 	DEFM	'two (2) players, one on the left '
 JUMPER	DEFL	$
 	ORG	3C00H+58
 	DEFB	'.'
 	ORG	JUMPER
 	DEFM	'and one on the   right.  The steering'
 	DEFM	' works as follows:'
 	DEFW	0A0AH
 	DEFM	'          LEFT PLAYER            RIGHT PLAYER'
 	DEFB	0AH
 JUMPER	DEFL	$
 	ORG	3C00H+59
 	DEFB	'.'
 	ORG	JUMPER
 	DEFM	'              W                       I'
 	DEFB	0AH
 	DEFM	'            A   S                   J   K'
 	DEFB	0AH
 	DEFM	'              Z                       M'
 	DEFW	0A0AH
 JUMPER	DEFL	$
 	ORG	3C00H+60
 	DEFB	'.'
 	ORG	JUMPER
 	DEFM	'To change direction, all a player '
 	DEFM	'must do is press the letter   corres'
 	DEFM	'ponding to the new desired direction.'
 	DEFW	0A0AH
 	DEFM	'Enter speed factor 0-9 (0=Fast,9=Slow)'
 	DEFB	0
 	DEFW	0D17H
 	DEFW	0D0DH
 	DEFB	0DH
 JUMPER	DEFL	$
 	ORG	3C00H+61
 	DEFB	'.'
 	ORG	JUMPER
 DOUBLE	DEFB	17H
 	DEFB	0
 NOTICE	DEFM	'** NOTE: This program was authored by DAG **'
 	DEFB	0DH
 	DEFB	0DH
 	DEFM	'CONVERSION TO RUN ON LEVEL I OR II 4-K
 	DEFB	0DH
 	DEFM	'AND LOADING COSMETICS BY KIM WATT.
 	DEFW	0D0DH
 	DEFM	'6/80'
 ZZZZZZ	DEFB	0DH
 TERMIN	DEFB	0
 	ORG	3C00H+640
 	DEFM	'                                                                '
 	DEFM	'                                                                '
 	ORG	3C00H+576
 	DEFM	'TYPE "/" AND PRESS <ENTER> TO BEGIN !                           '
 	ORG	3C00H+62
 	DEFM	'..'
 	ORG	4020H
 	DEFW	3C00H+576+50
 	END	MYNAME
                                                        '
 	ORG	3C00H+576
 	DEFM	'TYPE "/" AND PRESS <ENTER> TO BEGIN !                           '
 	ORG	3C00H+62
 	DEFM	'..'
 	ORG	4020